home *** CD-ROM | disk | FTP | other *** search
/ Power Programmierung / Power-Programmierung (Tewi)(1994).iso / magazine / drdobbs / 1987 / 10 / brownlst.oct < prev    next >
Text File  |  1987-09-14  |  87KB  |  1,983 lines
  1. * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *
  2. *
  3. *   THIS FILE CONTAINS EXCERPTS FROM THE APPLETALK SOURCES, 
  4. *     VERSION 39, AUGUST 1985, AS MODIFIED BY DARTMOUTH COLLEGE
  5. *    TO PRODUCE THE ASYNC APPLETALK DRIVER (.BPP) VERSION 1.2
  6. *    (ASYNC APPLETALK INSTALLER VERSION 2.1) OF MAY 1987.
  7. *
  8. *     THESE EXCERPTS CONTAIN INFORMATION OF TWO TYPES:
  9. *        1) CODE WRITTEN ENTIRELY AT DARTMOUTH COLLEGE;
  10. *        2) CODE WHICH IS FUNDAMENTALLY SIMILAR TO THE
  11. *            PRELIMINARY APPLETALK SOFTWARE DISTRIBUTED
  12. *            WITHOUT RESTRICTION AT THE APPLEBUS DEVELOPER'S
  13. *            CONFERENCE IN CUPERTINO, CA IN MAY, 1984.
  14. *
  15. *    PORTIONS OF THIS CODE ARE COPYRIGHT OF THE TRUSTEES OF
  16. *    DARTMOUTH COLLEGE OR APPLE COMPUTER INC.
  17. *
  18. *    THESE CODE SEGMENTS ARE PROVIDED FOR INFORMATION ONLY.  NO
  19. *    GUARANTEE OF CORRECT OPERATION IS PROVIDED.
  20. *
  21. *    FOR MORE INFORMATION ABOUT THIS CODE, CONTACT:
  22. *
  23. *    Rich Brown
  24. *    Manager of Special Projects
  25. *    Dartmouth College
  26. *    Kiewit Computer Center
  27. *    Hanover, NH 03755
  28. *    603/646-3648
  29. * 
  30. * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *
  31.  
  32. ***** file ALAPDEFS.A *****
  33.  
  34. ; AALAPdefs.a contains all the special definitions which were not
  35. ; needed for .MPP .
  36. ;
  37. ; .BPP et al should now use unmodified versions of:
  38. ;        {AIncludes}atalkequ.a
  39. ;        lapdefs.a
  40. ;        vardefs.a
  41. ;                            
  42. ; Created 31 Mar 87   reb 
  43. ;
  44. ; AALAP constant defs
  45. ;
  46. MaxLAPFrmLen EQU    586+13+3+2          ; DDP data + DDP hdr + LAP hdr + CRC
  47. FrameChar   EQU     $A5                 ; the Framing Char
  48. qFrmChar    EQU     -91                 ; for moveq instructions
  49. DLE         EQU     $10
  50. Xoff        EQU     $13
  51. Xon         EQU     $11
  52.  
  53. lapIM       EQU     $86                 ; I aM
  54. lapUR       EQU     $87                 ; yoU aRe (sorry for these names...)
  55. qlapIM      EQU     -122
  56. qlapUR      EQU     -121
  57.  
  58. noansalrt   EQU     -15998
  59. portncalrt  EQU     -15997
  60.  
  61. ; Added constant return value for AALAP --
  62. noAnswer        EQU     -95          ; same as excessCollsns in real AtalkEqu 
  63.  
  64. AAOfst          EQU      10000      ; 0 or 10000 (for final version)
  65.  
  66. ;+ MPP (Status calls to NBP, DDP and AALAP)
  67.  
  68. GetStats        EQU      400        ; (ABLAP) get the statistics 
  69. GetMyName       EQU      AAOfst+255 ; get the name of the ATalk driver
  70. (AALAP)
  71. GetChar         EQU      AAOfst+254 ; get the most recently received char
  72. (AALAP)
  73. GetLAPStatus    EQU      AAOfst+253 ; return AALAP status  (AALAP)
  74.  
  75. ;+ MPP (Control calls to NBP, DDP, and AALAP)
  76.  
  77. FirstAPP        EQU      AAOfst+237 ; First APP control call
  78. DoWarnings      EQU      AAOfst+237 ; Put up the specified alerts
  79. (AALAP)
  80. PutChar         EQU      AAOfst+238 ; Loop 'til TBMT, then output the char
  81. (AALAP)
  82. ReInitAALAP     EQU      AAOfst+239 ; ReInitialize the AALAP variables & SCC
  83. (AALAP)
  84. GetNNNN         EQU      AAOfst+240 ; Do NNNN using SysNetNum and sysLAPAddr
  85. (AALAP)
  86. SetBaud         EQU      AAOfst+241 ; Set the baud rate of the SCC
  87. (AALAP)
  88. LastAPP         EQU      AAOfst+241
  89.           EJECT
  90. ;
  91. ; LAP variables
  92. ;
  93. WDSPtr      EQU     MPPVarsEnd          ; (4) WDS pointer saved here on writes
  94. LAPWrtRtn   EQU     WDSptr+4            ; (4) return adrs of LAPWrite caller 
  95. SaveA45     EQU     LAPWrtRtn+4         ; (8) A4 and A5 saved here on interrupt
  96. SaveDskRtn  EQU     SaveA45+8           ; (4) DskRtnAdr saved here for
  97. PollProc
  98. SavePS      EQU     SaveDskRtn+4        ; (4) in AALAP, the real PollProc's
  99. address
  100. SaveBIn     EQU     SavePS+4            ; (4) .BIN DCE saved here (for close)
  101. SaveBOut    EQU     SaveBIn+4           ; (4) .BOUT DCE saved here (for close)
  102. SaveVects   EQU     SaveBOut+4          ; (16) SCC interrupt vectors saved
  103. here
  104. SaveRegs    EQU     SaveVects+16        ; (20) Registers saved here across
  105. PollProc
  106.  
  107. ;
  108. ; Variables for Lisa/Mac hardware differences
  109. ;
  110. VAVBufA     EQU     SaveRegs+20         ; Pointer to VIA or a $FF word
  111. STLth       EQU     6                   ; Size of STData area
  112. VSTData     EQU     VAVBufA+4           ; Data string to SCC after send
  113. VDisTxRTS   EQU     VSTData+1           ; This is the DisTxRTS byte
  114. EndOrigStuff EQU    VSTData+STLth       ;
  115.  
  116. ;
  117. ; AALAP varibles
  118. ;
  119. tWDSptr     EQU     EndOrigStuff+2      ; (4) WDS ptr of frame being tx
  120. qWDSptr     EQU     tWDSptr+4           ; (4) WDS of a queued DevMgr frame
  121. LastXmit    EQU     qWDSptr+4           ; (4) Ticks at time of last char sent
  122. LastRcv     EQU     LastXmit+4          ; (4) Ticks at time of last good
  123. received frame
  124. LAPStash    EQU     LastRcv+4           ; (4) Pointer to next received char's
  125. place
  126. LAPFetch    EQU     LAPStash+4          ; (4) Pointer to next char to xmit
  127. LAPInBuf    EQU     LapFetch+4          ; (4) Pointer to the LAP input buffer
  128. IMURwds     EQU     LAPInBUf+4          ; (8) WDS for IM or UR frames
  129. BusyBuf     EQU     IMURwds+8           ; (16) Holds up to 16 chars rcvd while
  130. doingRead
  131. BusyStash   EQU     BusyBuf+16          ; (4) pointer to next space in BusyBuf
  132. BusyFetch   EQU     BusyStash+4         ; (4) pointer to next char to remove
  133. IMURbuf     EQU     BusyFetch+4         ; (8) Holds IM or UR (starting at odd
  134. adrs)
  135. InputCRC    EQU     IMURBuf+8           ; (2) CRC for the receiver
  136. OutputCRC   EQU     InputCRC+2          ; (2) CRC for the transmit side
  137. RcvdLen     EQU     OutputCRC+2         ; (2) Number of chars received
  138. TxCount     EQU     RcvdLen+2           ; (2) Number of char's transmitted
  139. CRCBuf      EQU     TxCount+2           ; (2) Two bytes for the CRC for
  140. xmission
  141. RandomSeed  EQU     CRCBuf+2            ; (2) Seed for random number generator
  142. LastRxCh    EQU     RandomSeed+2        ; (2) Lsbyte is last rcvd char, else
  143. $FFFF
  144. AALAPbaud   EQU     LastRxCh+2          ; (2) Current baud rate of the LAP
  145. SentChar    EQU     AALAPbaud+2         ; (1) True if TxNextCh sent a char
  146. nFrmChr     EQU     SentChar+1          ; (1) True if we must send a FrameChar
  147. nCRC        EQU     nFrmChr+1           ; (1) True if we must send the CRC
  148. EscIn       EQU     nCRC+1              ; (1) Escaping flag for the receiver
  149. EscOut      EQU     EscIn+1             ; (1) Transmitter is sending an escaped
  150. char
  151. RcvdXoff    EQU     EscOut+1            ; (1) We received Xoff
  152. AALAPup     EQU     RcvdXoff+1          ; (1) true if we've handshook IM & UR
  153. AALAPstuck  EQU     AALAPup+1           ; (1) true if we have NNNN conflict
  154. InpState    EQU     AALAPstuck+1        ; (1) 0 = idle; <> 0 = in a frame
  155. stillBusy   EQU     InpState+1          ; (1) true if still processing a read
  156. nXon        EQU     stillBusy+1         ; (1) true if we sent Xoff
  157. SendingIMUR EQU     nXon+1              ; (1) true if sending AALAP control frame
  158.  
  159. _AssumeEq   (InpState+1),stillBusy         ; tst.w InpState(A4) in 
  160. _AssumeEq   (InpState**$FFFFFFFE),InpState ;   myPollProc fails otherwise
  161.  
  162.             IF      debug THEN          ; doing statistics
  163. XmitCount   EQU     SendingIMUR+1
  164. XOFFTOcount EQU     XmitCount+4
  165. OVRcount    EQU     XOFFTOcount+4
  166. RcvIntCount EQU     OVRcount+4
  167. XOFFcount   EQU     RcvIntCount+4
  168. XONcount    EQU     XOFFcount+4
  169. LongFrame   EQU     XONcount+4
  170. ShortFrame  EQU     LongFrame+4
  171. FrmCount    EQU     ShortFrame+4
  172. NoHandCnt   EQU     FrmCount+4
  173. CRCCount    EQU     NoHandCnt+4
  174. LenErrCnt   EQU     CRCCount+4
  175. BadDDP      EQU     LenErrCnt+4
  176. PPCount     EQU     BadDDP+4
  177. PPXoffCnt   EQU      PPCount+4
  178. DeferXmit   EQU      PPXoffCnt+4
  179. ABVarsEnd   EQU     DeferXmit+4
  180.             ELSE 
  181. ABVarsEnd   EQU     SendingIMUR+1        ; end of AALAP variables
  182.             ENDIF
  183.  
  184.  
  185. ***** file MPP.A *****
  186.  
  187. ... section removed ...
  188.  
  189. ;___________________________________________________________________________
  190. ;
  191. ; SCCConfig - set up the SCC for AppleBus
  192. ;___________________________________________________________________________
  193.  
  194. SCCConfig   LEA     OpenTbl,A0          ; A0 -> (common) open table
  195.             CMP.B   #$FF,MacTypeByte    ; Mac or Lisa?
  196.             BNE.S   @10                 ; Branch if Mac - configure it
  197.             BSR     ToSCC               ; Configure SCC to major settings
  198.             LEA     LOpenTbl,A0         ; A0 -> Lisa open table
  199. @10         BRA     ToSCC               ; Configure SCC and return
  200.  
  201. ... section removed ...
  202.  
  203. ToSCC       MOVE.L  SCCWr,A3            ; Point to SCC port B write registers
  204.             IF      PortA THEN
  205.             ADDQ    #ACtl,A3            ; Add in port A offset
  206.             ENDIF
  207. @10         MOVE    (A0)+,D0            ; Get next register number / control
  208. word
  209.             BEQ.S   CloseRTS            ; Zero is terminator
  210.             MOVE.B  D0,(A3)             ; Put out register number
  211.             ROR     #8,D0               ; Pickup control word
  212.             MOVE.B  D0,(A3)             ; Set to SCC
  213.             BRA.S   @10                 ; And keep going
  214.  
  215. ... section removed ...
  216.  
  217. ;_______________________
  218. ;
  219. ; Initialization tables
  220. ;_______________________
  221.  
  222. ;
  223. ; SCC Initialization table - common between Mac and Lisa
  224. ; Entry format: .BYTE control-value, control-reg-number
  225. ; Taken from the Zilog SCC Application note, 00-2957-02
  226.  
  227. OpenTbl     DC.B    ResetOurPort,9      ; ($40 or $80) Reset port
  228.             DC.B    $44,4               ; x16 clock, 1 stop, no parity
  229.             DC.B    $0,2                ; Interrupt vector = $00
  230.             DC.B    $C0,3               ; Rx is 8 bits, disable Rx
  231.             DC.B    $E2,5               ; Tx is 8 bits, Disable Tx; DTR, RTS
  232. on
  233.             DC.B    $0,6                ; No address
  234.             DC.B    $0,7                ; No Flag character
  235.             DC.B    $0,10               ; NRZ
  236.             DC.B    $56,11              ; Tx & Rx clock from BRG
  237.             DC.B    $2,14               ; BRG source = PCLK, BRG off
  238. ; enables
  239.             DC.B    $3,14               ; BRG on
  240.             DC.B    $C1,3               ; Rx on
  241.             DC.B    $EA,5               ; Tx on
  242. ; Interrupt controls
  243.             DC.B    MouseInts,15        ; enable DCD ints (for mouse)
  244.             DC.B    $10,0               ; reset external ints
  245.             DC.B    $10,0               ; reset external ints (twice)
  246.             DC.B    $13,1               ; Tx, Rx, Ext int enable
  247.             DC.B    MIE,9               ; Master Interrupt Enable
  248.             DC.W    0                   ; *** End of table ***
  249.  
  250.             IF      RAM THEN            ; Only need Lisa table if RAM-based
  251. ;
  252. ; SCC initialization table for Lisa
  253. ; Port A uses PCLK (@4.0 MHz TTL) to drive BRG; Port B uses 3.6864 MHz Xtal
  254. ;
  255.             IF      PortA THEN          ; configuration for Port A
  256. LOpenTbl    DC.B    $00,14              ; turn off BRG
  257.             DC.B    $6A,5               ; enable TX, RTS; DTR low
  258.             DC.B    $56,11              ; TTL clock, tx and rx use BRG
  259.             DC.B    $02,14              ; Use PCLK to feed BRG, BRG off
  260.             DC.B    $03,14              ; BRG on
  261.             DC.W    0
  262.             ELSE                        ; configuration for PortB
  263. LOpenTbl    DC.B    $00,14              ; turn off BRG
  264.             DC.B    $6A,5               ; enable TX, RTS; DTR low
  265.             DC.B    $D6,11              ; Crystal clock, tx and rx use BRG
  266.             DC.B    $00,14              ; Use crystal to feed BRG, BRG off
  267.             DC.B    $01,14              ; BRG on
  268.             DC.W    0
  269.             ENDIF
  270.  
  271. ;
  272. ; Mac initialization data (first is the post-transmitting SCC string)
  273. ;
  274. MacInitData DC.B    5,MDisTxRTS         ; ($60) Turn off drivers
  275.             DC.B    14,ResetClks        ; ($41) Reset missing clocks flag
  276.             DC.B    3,EnbRxSlv          ; ($DD) Enable receiver
  277.             DC.W    $2100               ; SR to enable SCC interrupts
  278.             DC.B    AbortDelay,0        ; Delay to send out abort bits (3.2B)
  279.             IF      RAM THEN
  280. ;
  281. ; Lisa initialization data
  282. ;
  283. LisaInitData DC.B   5,LDisTxRTS         ; ($E2) Turn off drivers
  284.             DC.B    14,ResetClks        ; ($41) Reset missing clocks flag
  285.             DC.B    3,EnbRxSlv          ; ($DD) Enable receiver
  286.             DC.W    $2500               ; SR to enable SCC interrupts
  287.             DC.B    34,0                ; Just delay this much on Lisa (3.2B)
  288.             ENDIF
  289.  
  290. ***** file LAP.A *****
  291.  
  292. ;_______________________________________________________________________
  293. ;
  294. ; LAP.TEXT - the LAP part of AALAP
  295. ;
  296. ; April-August, 1984
  297. ; Alan Oppenheimer and Larry Kenyon
  298. ;
  299. ; Rich Brown, Dartmouth College
  300. ; May 1987
  301. ;
  302. ; Version 1.2a6 Created qWDSptr to point at queued WDS  21 May 87   reb
  303. ; Version 1.2a5 Always check that TBMT is true before sending  19 May 87   reb
  304. ; Version 1.2a4 TintHnd, VBLHnd, RintHnd now call TxNextCh; only TintHnd
  305. ; clears interrupts (as it should be)   14 May 87   reb
  306. ; Version 1.2a3 Prefetching warning dialogs doesn't work; backed out  10 May 87 reb
  307. ; Version 1.2a2 tWDSptr now determines whether we're sending a frame;
  308. ; DoWarn now doesn't read the resource file  8 May 87   reb
  309. ; Version 1.2a1 Removed queueing from LAPWrite.  LAPWrite no longer 
  310. ; allocates memory, so it won't fail if called from
  311. ; interrupt handling.   19 Apr 87   reb
  312. ; Version 1.1b2 Changed noAnswer to -95 (so it can be handled like excessCollsns)
  313. ; LAPWrite returns noAnswer if AALAP not up; (30 Mar 87)
  314. ; GetNNNN  returns noAnswer or PortNotCF;
  315. ; Changed LAPWrite to return ddpLenErr if too long
  316. ; Version 1.1b1 Fixed PollProc to be more agressive about sucking chars
  317. ; from the SCC; added -1 SendChar value (sends Break);
  318. ; fix Initcursor bug in Dowarn 16 & 30 Dec 86   reb
  319. ; Version 1.1a1 Output an Xoff if called by PollProc during an input message
  320. ; 3 Nov 86   reb
  321. ; Version 1.0b2    Changed to set up SCC properly for Lisa  15 Oct 86
  322. ; (still has intermittent hangups, tho -- not diagnosed)
  323. ; Version 1.0b1 Changed last_valid_frame timer to 30 seconds; always send
  324. ; UR, even after un-matchable IM address
  325. ; Version 1.0a3 Fixed Status return buffer bug; SetBaud now takes actual
  326. ;                   baud rate; added GetLAPStatus call; copy entire message
  327. ; Version 1.0A2 Added alerts for NoAnswer, PortNotCf   (17 Jul 86   reb)
  328. ; Version 4.2   Int handlers now do IUS etc. more carefully (4 Jul 86)
  329. ; Version 4.1   Now escapes either parity Xon and Xoff (21 Apr 86)
  330. ; Version 4.0   First cut at AALAP (26 Oct-14 Dec 85)
  331. ... section removed ...
  332. ;
  333. ; COPYRIGHT (C) 1984 APPLE COMPUTER
  334. ;_______________________________________________________________________
  335.  
  336. ... section removed ...
  337.  
  338. ;___________________________________________________________________________
  339. ;
  340. ; MReInit - Control call to reinit AALAP and the SCC
  341. ;___________________________________________________________________________
  342.  
  343. MReInit     bsr.s AALAPWarm           ; Warm start ourselves
  344.             BRA   AbusExit            ; and return
  345. ;___________________________________________________________________________
  346. ;
  347. ; AALAPCold -- cold start for AALAP; called only once
  348. ;___________________________________________________________________________
  349.  
  350. AALAPCold   
  351. ;
  352. ; Allocate the input buffer (This should be alloc above BufPtr, not sysheap)
  353. ;
  354.             move.l  #maxLAPFrmLen,D0    ; get an AALAP input buffer
  355.             _newptr ,SYS                ; from the system heap
  356.             bne.s  WarmRTS              ; exit if bad
  357.             move.l  A0,LAPInBuf(a2)     ; otherwise save its pointer
  358. ;
  359. ; Clear out LAP variables
  360. ;
  361.             clr.l   WDSPtr(a2)
  362.             clr.l   tWDSptr(A2)
  363.             clr.l   LAPWrtRtn(A2)
  364.             clr.w   SysNetNum(a2)
  365.             clr.b   SysLAPAddr(a2)
  366.             clr.l   SavePS(A2)
  367.             sf      AALAPup(a2)
  368.             sf      AALAPstuck(a2)
  369. ;
  370. ; Setup SCC for AALAP
  371. ;
  372.             BSR     SCCConfig           ; Configure the SCC for Async
  373. AppleTalk
  374.             move    #9600,D0            ; and set up for 9600 baud
  375.             bsr      Set_Baud           ; 
  376. ;
  377. ; Reset all the LAP variables which don't irrevocably change the 
  378. ; state of the driver.  This routine can be called any time, only 
  379. ; killing the current message(s) in progress.
  380. ;
  381. AALAPWarm   move.l  Ticks,D0
  382.             move.l  D0,LastXmit(a2)
  383.             move.l  D0,LastRcv(a2)
  384.             lea     BusyBuf(a2),A0
  385.             move.l  A0,BusyStash(a2)
  386.             move.l  A0,BusyFetch(a2)
  387.             move.w  #$FFFF,LastRxCh(a2)
  388.             clr.l   tWDSptr(A2)
  389.             clr.l   qWDSptr(A2)
  390.             clr.w   TxCount(a2)
  391.             sf      RcvdXoff(a2)
  392.             sf      InpState(a2)
  393.             sf      EscIn(a2)
  394.             sf      SendingIMUR(A2)
  395.             sf      stillBusy(a2)
  396.             sf      nFrmChr(a2)
  397.             sf      nCRC(a2)
  398.             sf      nXon(A2)
  399. WarmRTS     rts
  400.  
  401.             EJECT
  402. ;___________________________________________________________________________
  403. ;
  404. ; Status - handle driver status request
  405. ;___________________________________________________________________________
  406.            _SUBR                        ; no one better call this...
  407. Status      MOVE.L  MPPVars,A2          ; A2 -> our variables
  408.             MOVEQ   #StatusErr,D0       ; Assume a status error
  409.             lea     CSParam(A0),A1      ; point at the CSParam buffer
  410.             move.w  CSCode(A0),D1       ; and get the CScode
  411.  
  412.             IF      Stats THEN
  413.             CMP.W   #GetStats,D1        ; Clear stats command?
  414.             BNE.S   @1                  ; check for "What's my Name?" if not
  415.             move.w  CSParam(A0),A1      ; CSParam contains a pointer to buffer
  416.             MOVE    SR,-(SP)
  417.             MOVE    #SCCLockout,SR      ; exclude interrupts to keep stats
  418. clean
  419.             ADD     #StatsStart,A2      ; point to stats we keep
  420.             MOVEQ   #(StatsLgCnt-1),D0
  421.             MOVEQ   #0,D1               ; zero for faster clearing
  422. @0          MOVE.L  (A2),(A1)+          ; return current value
  423.             MOVE.L  D1,(A2)+            ; then zero count
  424.             DBRA    D0,@0
  425.             MOVE    (SP)+,SR
  426.             bra.s   AbusExit
  427.             ENDIF
  428.  
  429. @1          cmp.w   #GetMyName,D1       ; is this a "what's my name" call?
  430.             bne.s   @2                  ; go if not
  431.             Move.l  MPP+18,(A1)+        ; move Pascal string from front of driver
  432.             move.b  MPP+22,(A1)         ; to beginning the buffer (5 chars)
  433.             bra.s   @4                  ; and exit with good status
  434.  
  435. @2          cmp.w   #GetChar,D1         ; is this a "get last char" call?
  436.             bne.s   @3                  ; go if not
  437.             move.w  LastRxCh(a2),(A1)   ; copy the character (word)
  438.             move.w  #$FFFF,LastRxCh(a2) ; and flag the character
  439.             bra.s   @4
  440.  
  441. @3          cmp.w   #GetLAPStatus,D1    ; is this a "get LAP status" call?
  442.             bne.s   AbusExit            ; go if not
  443.             move.b  AALAPup(A2),(A1)+   ; AALAPup?
  444.             move.b  AALAPstuck(A2),(A1)+;AALAPstuck?
  445.             move.w  AALAPbaud(A2),(A1)  ; What's the baud rate?
  446. @4          clr.l   D0                  ; return good status
  447.  
  448. AbusExit    MOVE.L  MPPDCE,A1           ; Make sure A1 has DCE address
  449. AbusExA1    MOVE.L  JIODone,-(SP)       ; This is how we exit (Prime, Control,
  450. Status)
  451. AbusRTS     RTS
  452.             SUBEND 'MYSTATUS'           ; this marks the AbusExit
  453.  
  454. Prime       BCLR    #DrvrActive,DCtlFlags+1(A1) ; *** V2.0C Fix Mac ROM bug
  455. ***
  456.             RTS                                 ; *** V2.0C Fix Mac ROM bug
  457. ***
  458.             EJECT
  459. ;_____________________________________________________________________
  460. ;
  461. ; MGetNNNN -- Do the NNNN, using the current values of SysLAPAddr and
  462. ;             SysNetNum.  Return bad status if it didn't work.
  463. ;
  464. ; On entry: A2 -> BPP variables
  465. ; On exit:  D0 = noErr (0) if we succeeded,
  466. ;                PortNotCF (-98) or
  467. ;                noAnswer  (-95) if not
  468. ;____________________________________________________________________
  469.  
  470. MGetNNNN    bsr.s   Get_NNNN            ; Use them just as they are
  471.             bra.s   AbusExit            ; return from the control calls
  472.  
  473. tries       EQU     -2                  ; counter for the tries
  474. endtime     EQU     -6                  ; end time
  475.  
  476. Get_NNNN    _SUBR   6
  477.             move.w  Ticks+2,RandomSeed(a2) ; randomize things
  478.             move.b  SysLAPAddr(a2),D0   ; Node number in D0
  479.             move    SysNetNum(a2),D1    ; Net number in D1
  480.             sf      AALAPup(a2)         ; we're not up yet
  481.             sf      AALAPstuck(a2)      ; and we're not in trouble either
  482.             move    #4,tries(a6)        ; tries counter (4 tries)
  483. @10         move.l  Ticks,D2
  484.             add.l   #30,D2              ; set endtime to the current time+30
  485.             move.l  D2,endtime(a6)      ; remember the ending time
  486.             moveq   #qlapIM,D2          ; get the lap type
  487.             move.w  SysNetNum(a2),D1    ; get the Net number
  488.             move.b  SysLAPAddr(a2),D0   ; and the node number
  489.             bsr     SendIMUR            ; and send it
  490. @20         clr     D0                  ; good status if things are OK
  491.             tst.b   AALAPup(a2)         ; did the magic work?
  492.             bne.s   NNNNexit            ; go if so
  493.             tst.b   AALAPstuck(a2)      ; is there an irreconcilable difference?
  494.             bne.s   NNNNstuck
  495.             move.l  endtime(a6),D2
  496.             cmp.l   Ticks,D2            ; otherwise, check the timer
  497.             bpl.s   @20                 ; loop if not timed out
  498.             sub     #1,tries(a6)        ; decr the counter
  499.             bgt.s   @10                 ; loop if non-zero
  500.             moveq   #noAnswer,D0        ; They don't want to talk
  501.             bra.s   NNNNexit
  502.  
  503. NNNNstuck   moveq   #PortNotCF,D0       ; They talk but say bad things
  504.  
  505. NNNNexit    tst.w   D0                  ; set CC
  506.             _Subend 'GETNNNN '          ; and return
  507.             EJECT
  508. ;___________________________________________________________________________
  509. ;
  510. ; MPutChar -- Kill output and send the char pointed to in the control call
  511. ;
  512. ; Entry:    A0 -> IOQelement
  513. ; Exit:     Return status is 0000   if noErr,
  514. ;                            BadIO  if timed out waiting for TBMT
  515. ;___________________________________________________________________________
  516.  
  517. SendBrk     equ     $12                 ; Sends Break (w/RTS) when sent to WR5
  518.  
  519. MPutChar    bsr.s   Put_Char
  520.             bra     AbusExit            ; and exit
  521.  
  522. Put_Char     _SUBR
  523.             move.w  CSParam(a0),D0      ; get the character (in an integer)
  524.             bmi.s   @10                 ; if it's 0..255, 
  525.             bsr     SendChar            ;    output the character
  526.             bra.s   @20                 ; and quit
  527.  
  528. @10         lea     BreakTbl,A0         ; 
  529.             move.b  #SendBrk,(A0)       ; set the break bit in WR5
  530.             bsr     ToScc               ; 
  531.             move.l  #10,A0              ; wait 10 ticks
  532.             _delay
  533.             move    #$EA,D0             ; Enable Tx, DTR, RTS
  534.             CMPI.B  #$FF,MacTypeByte    ; Mac or Lisa?
  535.             BNE.S   @15                 ; Branch if Mac (PortA & PortB are same)
  536.             move    #$6A,D0                 ; Lisa doesn't assert DTR
  537.             @15lea  BreakTbl,A0
  538.             move.b  D0,(A0)               ; and turn the Break off
  539.             bsr     ToSCC
  540.             clr     D0
  541.  
  542. @20         SUBEND 'MPUTCHAR'
  543.  
  544. breaktbl    dc.b    0,5      ; THIS WON'T MAKE ROMMABLE CODE
  545.             dc.w    0000
  546. ;_____________________________________________________________________
  547. ;
  548. ;  MSetBaud -- send the (integer) value in the CSParamblk to SCC as its Baud
  549. Rate
  550. ;  Entry:  A0 -> IOQelement
  551. ;  Exit:   noErr if aok
  552. ;          -1    if requesting 19,200 baud on a Lisa, port A (cannot be done)
  553. ;_____________________________________________________________________
  554. ; THIS WON'T MAKE ROMMABLE CODE!
  555. BaudConsts  DC.B    2,14                ; turn off BRG (so it doesn't count for
  556. a while)
  557. lsBaudVal   DC.B    0,12                ; LSByte of BRG
  558. msBaudVal   DC.B    0,13                ; MSByte of BRG
  559. BaudSrc     DC.B    0,14                ; turn it on again, with proper baud
  560. source
  561.             DC.W    0000                ; end of constant string
  562.  
  563. BaudTable   DC.W    1200,94,102         ; 1200 baud, Mac&LisaB , LisaA BRG
  564. constants
  565.             DC.W    2400,46,50          ; 2400 baud
  566.             DC.W    4800,22,24          ; 4800 baud
  567.             DC.W    9600,10,11          ; 9600 baud
  568.             DC.W    19200,4,-1          ; 19200 baud (but not for Lisa Port
  569. A...)
  570. BaudTblEnd  DC.W    -1                  ; sentinel
  571.  
  572. MSetBaud    move    CSParam(a0),D0      ; get the (integer) baud rate
  573.             bsr.s   Set_Baud
  574.             bra     AbusExit
  575.  
  576. Set_Baud    _SUBR                       ; D0 contains the actual desired baud
  577. rate
  578.             move.w  D0,AALAPbaud(A2)    ; save the current baud rate
  579.             lea     BaudTable,A0        ; point at the table
  580. @10         cmp.w   (a0),D0             ; does it match?
  581.             beq.s   @30                 ; go if so
  582.             addq.l  #6,A0
  583.             tst.w   (A0)                ; are we done?
  584.             bpl.s   @10                 ; loop if we didn't hit the sentinel
  585.             moveq   #-1,D0              ;
  586.             bra.s   @50                 ; and bail out
  587.  
  588. @30         moveq   #3,D1               ; set up for Mac port A/B (PCLK/BRG on)
  589.             CMPI.B  #$FF,MacTypeByte    ; Mac or Lisa?
  590.             BNE.S   @40                 ; Branch if Mac (PortA & PortB are
  591. same)
  592.          IF  PortA THEN                 ; Lisa ports A/B differ; Macs don't
  593.             addq.l  #2,A0               ; bump to Lisa PortA column
  594.          ELSE
  595.             moveq   #1,D1               ; Lisa portB works from Xtal, not PCLK
  596.          ENDIF
  597. @40         move.w  2(a0),D0            ; get value BRG (-1 if 19,200 on Lisa)
  598.             bmi.s   @50                 ; exit if negative
  599.  
  600. ; D0 now contains the value for the BRG
  601.             lea     BaudConsts,a0       ; point at the constants
  602.             move.b  d0,lsBaudVal-BaudConsts(a0) ; save the LSByte of the BRG
  603.             ror     #8,d0
  604.             move.b  d0,msBaudVal-BaudConsts(a0) ; and the MSByte of the BRG
  605.             move.b  d1,BaudSrc-BaudConsts(a0)   ; and the source for BRG
  606.             bsr     toSCC               ; and output it
  607.             clr     d0
  608. @50         _SUBEND 'MSETBAUD'
  609.             EJECT
  610. ;___________________________________________________
  611. ;
  612. ; MWriteLAP - write out a LAP packet
  613. ;
  614. ;   Call:
  615. ;       A0 -> IO queue element
  616. ;       A1 -> WDS. First entry must start as follows:
  617. ;                   +-----------------+
  618. ;                   | Destination addr|
  619. ;                   +-----------------+
  620. ;                   |                 |     [ for source addr ]
  621. ;                   +-----------------+
  622. ;                   |  LAP type code  |
  623. ;                   +-----------------+
  624. ;                   :                 :
  625. ;       A2 -> local variables
  626. ;
  627. ;   Return:
  628. ;       D0 = error code
  629. ;
  630. ; NOTE: for MPP, first two data bytes must be length
  631. ;____________________________________________________
  632.  
  633. MWriteLAP   MOVE.L  2(A1),A0            ; A0 -> first WDS entry
  634.             MOVEQ   #LAPProtErr,D0      ; Assume an error (2.3F)
  635.             TST.B   LAPType(A0)         ; Make sure protocol is a valid one
  636.             ble.s   MWRLAPex            ; Return error if not
  637.             MOVE.B  LAPDstAdr(A0),D2    ; D2 = destination address
  638.             bsr.s   LAPWrite            ; Write out the packet
  639. MWRLAPex    bra     AbusExit
  640.             EJECT
  641. ;___________________________________________________________________________
  642. ;
  643. ; LAPWrite - send a packet out an Async port.  Called both by MWriteLAP
  644. ; and DDPWrite.
  645. ;
  646. ;   Call:
  647. ;       A1 -> WDS (first entry must start as in MWriteLAP above)
  648. ;       A2 -> local variables
  649. ;       D2 = LAP destination address
  650. ;
  651. ;   Return:
  652. ;       D0 = noErr or the error code
  653. ;       Uses D1-D3,A0,A1,A3
  654. ;
  655. ; Save the WDS passed in
  656. ; If AALAP isn't up, return noAnswer
  657. ; Next, check the length of the frame for <= 603 bytes; return error if bad
  658. ; If we're currently sending a frame:
  659. ; if it's an IM/UR, simply return (WDS will be sent when done)
  660. ; if it's not, then stop (somehow we got two frames to send from DevMgr)
  661. ; If interrupts are on 
  662. ;    Update PollProc pointer if it needs it
  663. ;    Check that the AALAP is still working, sending IM/UR if necessary.
  664. ; Start sending the frame
  665. ; 
  666. ; This code relies on the Device Manager for queuing.  Here's how it works:
  667. ;
  668. ; General Rule #1: All operations initiated by the device manager 
  669. ; ultimately return to the DevMgr through jIOdone.
  670. ;
  671. ; General Rule #2:  All async operations which cannot complete immediately 
  672. ; return thru a RTS.  When the operation does complete, the (interrupt)
  673. ; routine can go thru jIOdone.
  674. ;
  675. ; Specific AppleTalk Rule #1:  All callers of LAPWrite have bra AbusExit
  676. ; code right after the call to LAPWrite.  This eventually jumps to jIOdone.
  677. ;
  678. ; Specific AppleTalk Rule #2:  Since they've taken care of the details,
  679. ; LAPWrite only has to remember two things: If we finish, we can return
  680. ; to our original caller (by jumping thru LAPWrtRtn to go to the device 
  681. ; manager);  If we don't finish, we should return to the caller's caller
  682. ; (which called the device manager in the first place).  Whew!
  683. ;___________________________________________________________________________
  684.  
  685. LAPWrite    move.l    (SP)+,LAPWrtRtn(A2) ; save the caller's adrs
  686.             move.l    A1,WDSptr(A2)       ; and the frame we're asked to send
  687.  
  688.             move.w    #noAnswer,D0
  689.             tst.b     AALAPup(a2)         ; is the AALAP up?
  690.             beq       LAPWexit            ; exit if bad
  691. ;
  692. ; Next compute the length of the WDS -- exit if it's bad
  693. ;
  694.             move.l  A1,A0                ; get the WDS pointer
  695.  
  696.             clr.l   D2                  ; D2 = number of data bytes in frame
  697.             clr.l   D1                  ; D1 = number of segments in WDS
  698.             cmp.w   #2,(a0)             ; is first segment too short?
  699.             ble.s   LAPWexit            ; go if it is
  700. @20         tst.w   (a0)                ; is WDS length = 0?
  701.             beq.s   @30                 ; go if so
  702.             add.w   (a0),d2             ; add in this length
  703.             addq    #1,d1               ; incr the segment counter
  704.             addq.l  #6,A0               ; bump the WDS pointer
  705.             bra.s   @20
  706.  
  707. ; D2 is the length of the message we've been asked to send
  708. ; D1 is the number of segments we've been presented with
  709. ; (A1 still has WDSptr)
  710.  
  711. @30         moveq   #LAPProtErr,D0
  712.             tst.l   d1                  ; is D1 (number of segments) < 1?
  713.             ble.s   LAPWexit            ; go if so (error)
  714.             moveq   #ddpLenErr,D0 
  715.             cmp.w   #603,D2             ; is the length > 603 (3 LAP + 600
  716. data)
  717.             bgt.s   LAPWexit            ; go if it's bad
  718. ;
  719. ; we can try to send WDS in A1 -- are we currently sending a frame?
  720. ;
  721.             tst.l   tWDSptr(a2)         ; are we presently sending a frame?
  722.             beq.s   @40                 ; go if not
  723.             tst.b   SendingIMUR(A2)     ; is it an IM or UR?
  724.             beq.s   @35                 ; go if not
  725.             tst.l   qWDSptr(A2)         ; is one already queued?
  726.             bne.s   @35                 ; go if so (stop)
  727.             move.l  A1,qWDSptr(A2)      ; save the (queued) WDS pointer
  728.            _statcount DeferXmit
  729.             rts   
  730. @35         pea     AALAP2in1           ; point at the string
  731.             DC.W    $ABFF               ; and trap 'em (in lieu of $A9FF)
  732.  
  733. ;
  734. ; WDS in A1 is OK to send now: if interrupts enabled, 
  735. ;    update PollProc and check time since last good frame
  736. ;
  737. @40         move    SR,D0
  738.             and     #$70,D0             ; is the interrupt mask <> 0?
  739.             bne.s   SendWDSptr          ; just send it 
  740. ; 
  741. ; Update our local PollProc pointer
  742. ;
  743.             move    SR,-(A7)            ; save the state
  744.             move    #SCCLockout,SR      ; turn off interrupts
  745.             lea     myPollProc,A1       ; A1 -> our PollProc
  746.             move.l  PollProc,D0         ; get the current PollProc address
  747.             cmp.l   D0,A1               ; have we already updated it?
  748.             beq.s   @50                 ; go if we have
  749.             move.l  D0,SavePS(A2)       ; else update our saved copy
  750.             move.l  A1,PollProc         ; and point the real PollProc at us
  751. @50         move    (A7)+,SR            ; and re-enable
  752. ;
  753. ; check for (Ticks - LastRcv) > 1800 - see if they're still there
  754. ;
  755.             move.l  Ticks,D0            ; have we received a frame recently?
  756.             sub.l   LastRcv(a2),D0
  757.             cmp.l   #1800,D0            ; (ticks - LastRcv) > 1800 (30 sec)?
  758.             bmi.s   SendWDSptr          ; go if not (send it)
  759.             bsr     Get_NNNN            ; do the IM/UR stuff
  760.             beq.s   SendWDSptr          ; go if it worked
  761.             move.w  D0,-(SP)            ; otherwise, save the status
  762.             bsr     DoWarn              ; else, warn them
  763.             move.w  (SP)+,D0            ; and return bad status
  764. ;
  765. ; Come here if we need to return immediately (status is in D0)
  766. ;
  767. LAPWexit    move.l   LAPWrtRtn(A2),A0   ; this'll get 'em to IOdone
  768.             jmp      (A0)               ; sooner or later
  769.  
  770. AALAP2in1    dc.b 24
  771.             dc.b     'AALAP - TWO MSGS AT ONCE'
  772.             align 2
  773.             EJECT
  774. ;____________________________________________________________________
  775. ;
  776. ; SendFrame -- Starts off transmission of a frame
  777. ;
  778. ; A0 points to the WDS of the frame to send
  779. ;
  780. ; SendFrame sets all the pointers, etc.  and then sends the FrameChar 
  781. ; ($A5).  The Transmit Interrupt Handler ships all the remaining bytes
  782. ; as they are needed.
  783. ;
  784. ;____________________________________________________________________
  785.  
  786. SendWDSptr  move.l  WDSptr(A2),A0       ; get the WDS to send
  787. SendFrame   move.w  (a0)+,D0            ; D0 = the length of the 1st segment
  788.             move.l  (a0)+,a1            ; a1 -> the first byte of 1st segment
  789.             move.l  a0,tWDSPtr(a2)      ; and save the pointer to rest of WDS
  790.             subq    #2,D0               ; Finagle the length and address
  791.             move    D0,TxCount(a2)      ;   of the segment (AALAP doesn't
  792.             addq.l  #2,A1               ;   send dest and source node)
  793.             move.l  a1,LAPFetch(a2)     ;
  794.             st      nCRC(a2)            ; we'll need to send a CRC
  795.             st      nFrmChr(a2)         ;    and a closing FrameChar
  796.             sf      EscOut(a2)          ; clear the Escape flag
  797.             clr     OutputCRC(a2)       ; and the CRC
  798.             moveq   #qFrmChar,D0        ; load a FrameChar
  799.             bra.s   SendSCC             ; and kick off the frame
  800.            EJECT
  801. ;____________________________________________________________________
  802. ;
  803. ; LAPSend -- send the next byte in the LAP frame
  804. ;
  805. ; This routine checks to see if we're flow-controlled, if not, it
  806. ; gets the next char, accumulates the CRC, generates DLE's as 
  807. ; required, and calls the routine to place the byte in the SCC.
  808. ;
  809. ; It works from LAPFetch(a2), and advances it (and decrements TxCount)
  810. ; as necessary.
  811. ;
  812. ; If we sent a char, then we set SentChar(A2) to true
  813. ;____________________________________________________________________
  814.  
  815. LAPSend     tst.b   RcvdXoff(a2)        ; are we flow controlled?
  816.             bne.s   LAPSendRTS          ; go if so
  817.  
  818.             move    TxCount(a2),D3      ; get the remaining length
  819.             ble.s   LAPBadCount         ; go if zero or negative
  820.             cmp.w   #maxLAPFrmLen,D3    ; check its length
  821.             bgt.s   LAPBadCount         ; go if too big
  822.  
  823.             move.l  Ticks,LastXmit(a2)  ; remember when we last sent a char
  824.             subq    #1,D3               ; decr the count
  825.             move.l  LAPFetch(a2),a0     ;
  826.             move.b  (a0)+,D0            ; and fetch the character, bumping the ptr
  827.  
  828.             tst.b   EscOut(a2)          ; are we escaping this char?
  829.             bne.s   @15                 ; go if yes -- it's already in CRC
  830.             lea     OutputCRC(a2),a3    ; point at the output CRC Accumulator
  831.             bsr     NextCRC             ; accumulate the un-processed char
  832.  
  833.             cmp.b   #DLE,D0             ; test for DLE, Xon, Xoff, FrameChar
  834.             beq.s   @10                 ; go if it's a special one
  835.             cmp.b   #FrameChar,D0
  836.             beq.s   @10
  837.             move.b  D0,D1
  838.             and.b   #$7F,D1             ; is it a XON or XOFF (either parity)?
  839.             cmp.b   #Xoff,D1
  840.             beq.s   @10
  841.             cmp.b   #Xon,D1
  842.             bne.s   @20                 ; go if it's just a normal character
  843.  
  844. @10         st      EscOut(a2)          ; remember that we're escaping
  845.             moveq   #DLE,D0             ; data to send is a DLE
  846.             bra.s   SendSCC             ;  (and don't update the pointer/len)
  847.  
  848. @15         eor     #$40,D0             ; come here if we're escaping this char
  849. @20         move.l  a0,LAPFetch(a2)     ; update the pointer
  850.             move    D3,TxCount(a2)      ;    and the remaining length
  851.             sf      EscOut(a2)          ;
  852. ;                                       ; D0 has the next char to send
  853. ;           bra.s   SendSCC             ; and send the character
  854. ;
  855. ; SendSCC -- sends D0 to the SCC Write Data Register
  856. ;            Assumes that SCC is ready (TBMT is true)
  857. ; Returns D0 = 0
  858. ; uses A1
  859. ;
  860. SendSCC     st      SentChar(A2)        ; remember we sent a char
  861.             move.l  SCCWr,a1            ; point at the SCC Write Control
  862.             IF      PortA THEN
  863.             addq.l  #ACtl,a1            ; add in the offset for Port A
  864.             ENDIF
  865.             move.b  D0,SCCData(a1)      ; output the character
  866.             moveq   #0,D0               ; clear the return status
  867. LAPSendRTS  rts                         ; and return
  868. LAPBadCount pea     BadCntStr
  869.             DC.W    $ABFF               ; Trap 'em (not $A9FF)
  870.             rts
  871. BadCntStr    DC.B       10
  872.             DC.B    'Bad length'
  873.             align 2
  874.             EJECT
  875. ;____________________________________________________________________
  876. ;
  877. ; SendChar -- Synchronously wait for TBMT and send another character
  878. ;       Use Ticks to watch for 1/2 sec timeout, so we don't hang forever
  879. ;
  880. ; Entry:        D0 = char to send
  881. ; Exit:         D0 = 0000 if OK
  882. ;               D0 = BadTBMT if we timed out (-3110)
  883. ;               A0,A1,D2 changed
  884. ;____________________________________________________________________
  885.  
  886. SendChar    _SUBR
  887.             move    Ticks,D2            ; fail-safe counter
  888.             add.l   #30,D2              ; bump by 1/2 second
  889. @10         bsr.s   TestTBMT            ; look to see if we can send it
  890.             bne.s   @20                 ; go if we can 
  891.             cmp.l   Ticks,D2            ; did we time out?
  892.             bpl.s   @10                 ; go if not
  893.             move    #-3110,D0           ; BadTBMT return code
  894.             bra.s   @40
  895.  
  896. @20         bsr.s   SendSCC              ; else send it
  897.  
  898. @40         _SUBEND 'SENDCHAR'
  899. ;
  900. ; Check state of TBMT - sets CCR to state of TBMT
  901. ; Uses A0
  902. ;
  903. TestTBMT     movem.l SCCRd,A0            ; point at the SCC
  904.             IF      PortA THEN
  905.             addq.l  #Actl,A0
  906.             ENDIF
  907.             btst    #TxEmptyBit,(a0)     ; is the TBMT set?
  908.             rts                          ; return
  909.             EJECT
  910. ;____________________________________________________________________
  911. ;
  912. ; TIntHnd -- this code catches the Tx Buffer Empty interrupts from
  913. ;      the SCC and tries to send another character.  If it could not
  914. ;      send a character, it clears the Tx Pending bit, so that the SCC
  915. ;      will not interrupt again.  Finally (in any case) it also resets 
  916. ;      the highest interrupt under service (IUS) in the SCC to clear
  917. ;      the interrupt before returning.
  918. ;
  919. ; On entry, A0/A1 point to the SCC control read/write registers.
  920. ; Like a normal interrupt handler, it must preserve D4-D7 and A4-A7
  921. ;____________________________________________________________________
  922.  
  923. TIntHnd     move.l  MPPVars,a2          ; point at the MPP Variables
  924.             _statcount XmitCount        ;
  925.  
  926.             sf      SentChar(A2)        ; 
  927.             bsr.s   TxNextCh            ; try to send another char
  928.  
  929.             tst.b   SentChar(A2)        ; did we?
  930.             bne.s   TintIUS             ; go if so
  931.             move.l  SCCWr,A1            ; otherwise reset TxPend 
  932.             IF      PortA THEN
  933.             addq.l  #Actl,A1
  934.             ENDIF
  935.             move.b  #$28,(A1) 
  936. TIntIUS     bra     DoIUS               ; and reset the highest IUS
  937.  
  938. ;___________________________________________________________________________
  939. ;
  940. ; TxNextCh -- try to send (in this order)
  941. ;          the next character of the segment, or 
  942. ;          the next segment, or 
  943. ;          the CRC, or 
  944. ;          the trailing FrameChar.
  945. ;
  946. ; If a complete frame which was initiated by the device manager has 
  947. ; been sent, we should jump thru IODone (asking the DevMgr for more 
  948. ; to do).  Otherwise, (it was an IM or UR) we look to see if there 
  949. ; is a frame from the DevMgr queued (in WDSptr).  If so, we start 
  950. ; sending it, otherwise, we simply RTS.
  951. ;___________________________________________________________________________
  952.  
  953. TxNextCh    move.l  tWDSPtr(a2),D0      ; D0 -> WDS in progress
  954.             beq.s   TxNextRTS           ; if nil, just exit (no message)
  955.             tst.w   TxCount(A2)         ; is there more of the segment to send
  956.             bne     LAPSend             ; if so, send next character
  957.             
  958. @5          move.l  D0,A0               ; otherwise, point at the WDS
  959.             tst     (a0)                ; check the next length
  960.             beq.s   @10                 ; go if it's zero (end of the frame)
  961.             move    (a0)+,TxCount(a2)   ; otherwise, update TxCount and
  962.             move.l  (a0)+,LAPFetch(a2)  ;    and LAPFetch
  963.             move.l  a0,tWDSptr(a2)      ; and update the tWDSPtr
  964.             bra     LAPSend             ; and send it off
  965. ;
  966. ; Now send the CRC
  967. ;
  968. @10         tst.b   nCRC(a2)            ; do we need to send a CRC?
  969.             beq.s   @20                 ; go if not
  970.             sf      nCRC(a2)            ; don't need one now
  971.             move    outputCRC(a2),D0    ; get the two CRC bytes
  972.             ror.w   #8,D0               ; swap them
  973.             lea     CRCBuf(a2),a0       ; point at the CRC Tx Buffer
  974.             move    D0,(a0)             ; save the CRC bytes
  975.             move.l  a0,LAPFetch(a2)     ; and save the fetch pointer
  976.             move    #2,TxCount(a2)      ; save the length, too
  977.             bra     LAPSend             ; and send them off
  978. ;
  979. ; We've sent the CRC, now send the closing FrameChar
  980. ;
  981. @20         tst.b   nFrmChr(a2)         ; do we need to send a FrameChar?
  982.             beq.s   @30                 ; go if not
  983.             sf      nFrmChr(a2)         ;
  984.             moveq   #qFrmChar,D0        ; get $A5
  985.             bra     SendSCC             ; send it and exit
  986. ;
  987. ; We've sent a full frame, now clean up
  988. ;
  989. @30         clr.w   TxCount(a2)         ; clear the TxCount
  990.             clr.l   tWDSPtr(a2)         ; clear the tWDSptr (no longer sending)
  991. ;
  992. ; Now decide whether to return, wakeup the Dev. Mgr, or start a queued frame
  993. ;
  994.             tst.b   SendingIMUR(A2)     ; were we sending an IM or UR?
  995.             beq.s   NotIMUR             ; go if not
  996.             sf      SendingIMUR(A2)     ; well, we're not anymore
  997.             move.l  qWDSptr(A2),D0      ; is there a queued frame?
  998.             beq.s   TxNextRTS           ; go if not
  999.             move.l  D0,A0
  1000.             bra     SendFrame           ; otherwise, start sending it
  1001. TxNextRTS   rts                         ; otherwise, return (RTS)
  1002. ;
  1003. ; We weren't sending IM/UR so we must have finished a msg from the 
  1004. ; device mgr.  Therefore, we should return to the Device Manager.
  1005. ;
  1006. NotIMUR     clr.l   qWDSptr(A2)         ; clear out the WDS
  1007.             moveq   #0,D0               ; good return status
  1008.             bra     LAPWexit            ; and go thru LAPWrtRtn to IOdone
  1009.             EJECT
  1010. ;___________________________________________________________________________
  1011. ;
  1012. ; RandomWord - generate a random number
  1013. ;
  1014. ;   Call:
  1015. ;       RandomSeed(A2) = seed
  1016. ;
  1017. ;   Return:
  1018. ;       D0 = random number (CCR set to it)
  1019. ;___________________________________________________________________________
  1020.  
  1021. RandomWord  MOVE    RandomSeed(A2),D0   ; D0 = current seed
  1022.             MULU    #773,D0             ; Times 773
  1023.             ADDQ    #1,D0               ; Plus 1
  1024.             MOVE    D0,-(SP)            ; Save high byte on stack
  1025.             LSL     #8,D0               ; Put low byte into high byte
  1026.             MOVE.B  (SP)+,D0            ; And high byte into low byte
  1027.             MOVE    D0,RandomSeed(A2)   ; Set back in seed
  1028.             RTS
  1029.             EJECT
  1030. ;________________________________________________________________________
  1031. ;
  1032. ; VBL handler - come here every VBLtimer ticks. Used to check for long 
  1033. ; output puases; if we stop for > 1 second, we expermientally send
  1034. ; the next character.
  1035. ;   A0 -> VBL queue element
  1036. ;________________________________________________________________________
  1037.  
  1038. VBLHnd      MOVE    #VBLtimer,VBLCount(A0) ; Better re-init VBL count
  1039.             MOVE.L  MPPVars,A2             ; A2 -> local variables
  1040. ;
  1041. ; Have we sent an Xoff (did we set nXon)?  If so, try to send an Xon
  1042. ;
  1043.             tst.b   nXon(A2)               ; do we need an Xon?
  1044.             beq.s   @20                    ; go if not
  1045.             bsr     TestTBMT               ; try to send it to the SCC
  1046.             beq.s   VBLHndRTS              ; quit if we couldn't send it
  1047.             moveq   #Xon,D0  
  1048.             bsr     SendSCC                ; send an Xon
  1049.             sf      nXon(A2)               ; and clear the flag
  1050.             bra.s   VBLHndRTS              ; and quit
  1051. ;
  1052. ; Check for long pause during transmit
  1053. ;
  1054. @20         tst.l   tWDSptr(A2)         ; do we have anything to send?
  1055.             beq.s   VBLHndRTS           ; return if not
  1056.             move.l  Ticks,D0
  1057.             sub.l   LastXmit(a2),D0     ; if (ticks - LastXmit) > 60 then
  1058.             cmp     #60,D0              ; let's try to send another char
  1059.             bmi.s   VBLHndRTS
  1060.             bsr     TestTBMT            ; is TBMT set (can we send another char?)
  1061.             beq.s   VBLHndRTS           ; go if not
  1062.             sf      RcvdXoff(a2)        ;
  1063.             _statcount XOFFTOcount
  1064.             MOVE    #SCCLockout,SR      ; exclude SCC interrupts (VIA priority < SCC)
  1065.             bsr     TxNextCh            ; otherwise, do another character
  1066. VBLHndRTS   rts                         ; this'll restore SR et al
  1067.             eject
  1068. ;___________________________________________________________________________
  1069. ;
  1070. ;   myPollProc -- AALAP PollProc addendum (predendum?):
  1071. ;
  1072. ;   The AALAP needs a bit of a PollProc, since it will lose characters
  1073. ;   whenever the disk spins.  Of course, all good Macintosh programmers
  1074. ;   know that the Printer Port (PortB) isn't polled by the disk driver
  1075. ;   since there's just not enough horsepower to go around.
  1076. ;
  1077. ;   The PollProc is called by the disk driver to poll PortA.  We
  1078. ;   execute a snippet of code before the real PollProc, and send an 
  1079. ;   Xoff to the other end if we're receiving or processing a message 
  1080. ;   while the disk is spinning.  Then we transfer to the real PollProc.
  1081. ;
  1082. ;   This routine preserves all regs except the SR.  It does this by
  1083. ;   reserving a longword on the stack, and then stuffing the SavePS
  1084. ;   value in it.  If it's zero, then there wasn't a PollProc, and we
  1085. ;   pop that value off the stack and return to the disk driver.  If
  1086. ;   that value wasn't zero, then the real PollProc's address will be
  1087. ;   on the top of the stack, and we go there.  The disk driver's return
  1088. ;   address will be left on the stack, allowing the PollProc to return
  1089. ;   normally.
  1090. ;
  1091. ;   InpState and stillBusy must both be in the same word.  The 
  1092. ;   tst.w InpState(A2) below fails otherwise.
  1093. ;___________________________________________________________________________
  1094.  
  1095. myPollProc  subq    #4,A7                 ; save space for a return adrs
  1096.             move.l  A2,-(SP)              ; and save A2 
  1097.             move.l  MPPVars,A2            ; point at the MPP locals
  1098.             tst.b   nXon(A2)              ; have we already sent an Xoff?
  1099.             bne.s   myPPexit              ; go if so
  1100.             tst.w   InpState(A2)          ; are we receiving or processing a message?
  1101.             beq.s   myPPexit              ; go if not
  1102.  
  1103.             movem.l A0/A1/D0,-(SP)        ; save regs 
  1104. @10         bsr     StashSCCch            ; grab a char from the SCC, save it
  1105.             bne.s   @10                   ; loop 'til it's empty
  1106.             statcount PPCount
  1107.             bsr     TestTBMT              ; is it OK to send the Xoff?
  1108.             beq.s   @30                   ; go if not
  1109.             moveq   #Xoff,D0
  1110.             bsr     SendSCC               ; send Xoff
  1111.             st      nXon(A2)              ; and remember we need Xon
  1112.             statcount PPXoffCnt
  1113. @30         movem.l  (SP)+,A0/A1/D0       ; restore the regs
  1114.  
  1115. myPPexit    move.l   SavePS(A2),4(SP)     ; move address onto stack (sets CC)
  1116.             movea.l (SP)+,A2              ; restore A2
  1117.             bne.s    @20                  ; go if PollProc adrs <> 0 (use it)
  1118.             addq.l   #4,SP                ; else pop the (nil) adrs
  1119. @20         rts                            ; and go there
  1120.  
  1121.             EJECT
  1122. ;___________________________________________________________________________
  1123. ;
  1124. ;  ExtIntHnd -- catch the External or Status Interrupts from the SCC
  1125. ;
  1126. ;  Checks for mouse interrupt, passes control if it is one, else resets
  1127. ;  the external/status SCC interrupts.
  1128. ;___________________________________________________________________________
  1129.  
  1130. ExtIntHnd   btst    #DCDbit,D1          ; did the DCD bit change (mouse moved)
  1131.             beq.s   @10                 ; go if not
  1132.             move.l  MouseVector,A3      ; else, point at the mouse handler
  1133.             jmp     (A3)                ; and go there
  1134.  
  1135. @10         move.b  #$10,(a1)           ; reset ext interrupts
  1136.             move.b  #$10,(a1)           ;    (twice)
  1137.             move.b  #ResetIUS,(a1)      ; Reset Highest IUS in SCC (to WR0)
  1138.             rts
  1139.             EJECT
  1140. ;___________________________________________________________________________
  1141. ;
  1142. ; RIntHnd  - SCC receive interrupt handler
  1143. ;
  1144. ;   Called: A0 -> SCC control read register
  1145. ;           A1 -> SCC control write register
  1146. ;
  1147. ; This code is structured differently from the ABLAP code, since
  1148. ; the arrival rate of the chars is so much slower for AALAP.  Normal
  1149. ; ABLAP routines call ReadPacket and ReadRest to get pieces or the rest
  1150. ; of the frame as they arrive in real time.  With AALAP, the character
  1151. ; arrival rate is so slow that we copy the entire frame into an
  1152. ; interrupt-time buffer.
  1153. ;
  1154. ; When we receive a good frame, we then pass control to the appropriate
  1155. ; protocol handler, which then makes calls on ReadPacket and ReadRest to
  1156. ; dole out the characters as necessary.
  1157. ;
  1158. ; Like all Mac interrupt handlers, it must preserve D4-D7 and A4-A7.
  1159. ; and return with a RTS instruction.
  1160. ;
  1161. ; Since the default DDP socket listener is quite slow (3-4 msec to process
  1162. ; a newly received message) we set up a buffer to contain characters
  1163. ; which arrive during the time the socket listener is in control.  We
  1164. ; set a flag (stillBusy) to indicate that we're still busy, and save the
  1165. ; chars in BusyBuf.
  1166. ;_________________________________________________________________________
  1167.  
  1168. SpIntHnd
  1169. RIntHnd     move.l  MPPVars,A2          ; A2 -> driver variables
  1170.             _statcount RcvIntCount      ; remember the number of Rcv
  1171. interrupts
  1172.  
  1173. RIntHnd10   bsr     NextChar            ; handle next char (from BusyBuf or
  1174. SCC)
  1175.             beq     RIntRTS             ; quit if no data
  1176.  
  1177.             and     #$00FF,D0           ; use only eight bits
  1178.             move.w  D0,LastRxCh(a2)     ; remember the char
  1179. ;
  1180. ; Check for flow control from other side
  1181. ;
  1182. @15         move.b  D0,D1               ; check for either parity Xon/Xoff
  1183.             and.b   #$7F,D1
  1184.             cmp.b   #Xoff,D1            ; is it a control-S?
  1185.             bne.s   @20                 ; go if not
  1186.             _statcount XOFFcount        ; count it
  1187.             st      rcvdXoff(a2)        ; and remember we received Xoff
  1188.             bra.s   RIntHnd10           ; loop for another char
  1189.  
  1190. @20         cmp.b   #Xon,D1             ; or is it a control-Q?
  1191.             bne.s   @30                 ; go if not
  1192.             _statcount XONcount
  1193.             sf      rcvdXoff(a2)
  1194.             bsr     TestTBMT            ; is the tx empty?
  1195.             beq.s   RIntHnd10           ; loop if not
  1196.             bsr     TxNextCh            ; otherwise, start up Tx side again
  1197.             bra.s   RIntHnd10           ; loop for another char
  1198. ;
  1199. ; Watch out for framing characters
  1200. ;
  1201. @30         cmp.b   #FrameChar,D0       ; is it a framing character?
  1202.             beq.s   GotFrmCh            ;    go if so
  1203.             tst.b   InpState(a2)        ; are we in a frame?
  1204.             beq.s   RintHnd10           ;    loop for another char
  1205.             EJECT
  1206. ;
  1207. ; Maybe this is a data char -- check the frame length
  1208. ;
  1209.             cmp     #MaxLAPFrmLen,rcvdlen(a2) ; is the frame too long?
  1210.             bls.s   @50                 ; go if it's OK
  1211.             _statcount LongFrame        ; remember the long frame
  1212.             sf      InpState(a2)        ; go idle
  1213.             bra.s   RIntHnd10           ; loop for another char
  1214. ;
  1215. ; We have a real char -- un-escape it
  1216. ;
  1217. @50         cmp.b   #DLE,D0             ; is it a DLE?
  1218.             bne.s   @90                 ; go if not
  1219.             st      EscIn(a2)           ; remember we've seen an escape
  1220.             bra.s   RIntHnd10
  1221. ;
  1222. ; This is a data char -- complete any escaping, accumulate the CRC
  1223. ;
  1224. @90         tst.b   EscIn(a2)           ; should we escape it?
  1225.             beq.s   @100                ; go if not
  1226.             eor     #$40,D0             ; xor with $40
  1227.             sf      EscIn(a2)           ; and clear the escape flag
  1228.  
  1229. ; now we've got a good char
  1230. @100        lea     inputCRC(a2),a3     ; point at the CRC accumulator
  1231.             bsr     NextCRC             ; update the CRC accum using byte in
  1232. D0
  1233.             move.l  LAPStash(a2),a0     ; point at the next free char in
  1234. buffer
  1235.             move.b  D0,(a0)+            ; save the char in the buffer, bump the
  1236. pointer
  1237.             addq    #1,rcvdlen(a2)      ; increment the bytes-read counter
  1238.             cmp     #3,rcvdlen(a2)      ; have we read in exactly three chars?
  1239.             bne.s   @110                ; go if not
  1240.             move.l  LAPInBuf(a2),a0     ; otherwise point at the LAPInBuf
  1241. @110        move.l  a0,LAPStash(a2)     ; and update the pointer
  1242.             bra     RIntHnd10           ; loop for another char
  1243.  
  1244. RIntRTS     bra     DoIUS               ; reset Highest IUS and return
  1245.  
  1246. ;
  1247. ; We've discovered a FrameChar -- check if we're done or just starting
  1248. ;
  1249. GotFrmCh    tst.b   InpState(a2)        ; are we in a frame?
  1250.             beq.s   FrmStart            ;  go if not (we will be)
  1251.  
  1252. FrmEnd      cmp     #2,rcvdlen(a2)      ; found closing char
  1253.             bhi.s   CheckCRC            ;    go if frame is long enough
  1254.             _statcount ShortFrame       ; else, flag that we got a short frame
  1255.                                         ;    and fall into FrameStrt
  1256. ;
  1257. ; We're in a frame now!
  1258. ;
  1259. FrmStart    lea     toRHA(a2),a3        ; a3 -> RHA (holds 1st 5 bytes)
  1260.             move.b  sysLAPAddr(a2),(a3)+ ; copy the node number
  1261.             move.b  sysABridge(a2),(a3)+ ; and the bridge address
  1262.             move.l  a3,LAPStash(a2)     ; remember where next byte goes
  1263.             st      InpState(a2)        ; change the InpState to in_msg
  1264.             sf      EscIn(a2)           ; and we're not escaping data
  1265.             clr     InputCRC(a2)        ; no CRC yet
  1266.             clr     rcvdlen(a2)         ; no data, either
  1267.             bra.s   RIntRTS
  1268.             EJECT
  1269. ;
  1270. ; We received a complete frame -- check the CRC
  1271. ;
  1272. CheckCRC
  1273.             sf      InpState(a2)        ; we're not in a frame now
  1274.             tst     InputCRC(a2)        ; is the CRC zero?
  1275.             beq.s   LAPDemux            ; go if it is OK
  1276.             _statcount CRCCount         ; save the statistic
  1277.             bra.s   RIntRTS             ; and exit
  1278. ;
  1279. ; Come here on receipt of a good frame.  We've cleared the InpState
  1280. ; to indicate we're out of a frame.
  1281. ;
  1282.  
  1283. LAPDemux    _statcount FrmCount         ; log another good frame
  1284.             move.l  Ticks,LastRcv(a2)   ; remember this frame's arrival time
  1285.             lea     2+toRHA(a2),a3      ; a3 -> LAP type byte
  1286.             MOVE.B  (A3)+,D0            ; Get the LAPtype, bump pointer
  1287.             tst.b   D0
  1288.             BMI     LAPIn               ; If minus, it's a LAP packet
  1289.  
  1290. ;
  1291. ; Got a data packet - look for a protocol handler
  1292. ;
  1293.             tst.b   AALAPup(a2)         ; but first, is the AALAP up?
  1294.             beq.s   @60                 ; go if it's not up
  1295.             MOVEQ   #(LAPTblSz-1),D2    ; D2 = index into active protocols list
  1296. @30         CMP.B   Protocols(A2,D2),D0 ; Match?
  1297.             DBEQ    D2,@30              ; (If none, D2 is negative - 3.1F)
  1298.             LSL.W   #2,D2               ; Make D2 a longword index into Handlers
  1299. ;
  1300. ; Got a protocol handler -- Compute the desired length of the message in D1
  1301. ;
  1302.             move.b  (a3)+,D1            ; Get MSByte of the length into D1
  1303.             and     #3,D1               ; mask for two lsbits
  1304.             LSL     #8,D1               ; Move to proper position
  1305.             MOVE.B  (a3)+,D1            ; D1 = total length
  1306.             move    rcvdlen(a2),D0      ; D0 = total chars received (DDP + LAP
  1307. + CRC)
  1308.             subq    #3,D0               ; disregard LAP type and CRC
  1309.             cmp     D1,D0               ; are they equal?
  1310.             beq.s   @40                 ; go if so
  1311.             _statcount LenErrCnt        ; save the stats
  1312.             bra     RIntRTS             ; and exit
  1313.  
  1314. @40         SUBQ    #2,D1               ; Subtract 2 for length bytes
  1315.             move    d1,RcvdLen(a2)      ; and remember the number of unread chars
  1316.             EJECT
  1317. ;___________________________________________________________________________
  1318. ;
  1319. ;       At this point, Handlers(A2,D2) points to the address of the protocol
  1320. ;       handler for this packet's protocol (or D2 is negative if there is
  1321. ;       none -- 3.1F). JMP to it with the following:
  1322. ;
  1323. ;       A0,A1 = SCC read/write addressses
  1324. ;       A2 = ptr to driver locals
  1325. ;       A3 = ptr into the RHA (first 5 bytes loaded)
  1326. ;       A4 will be the address of our read packet routine
  1327. ;       A5 will be saved for handler's usage (until packet's all in or error)
  1328. ;       D1 = length of packet still left to read (from header)
  1329. ;
  1330. ;       The protocol handler must obey the following conventions:
  1331. ;
  1332. ;       1) It must preserve, across the call, A0-A2, A4 and D1
  1333. ;       2) A6 and D4-D7 must be saved and restored if used.
  1334. ;       3) It must JSR to the routine at (A4) or 2(A4) with registers as defined
  1335. ;          there, for the purpose of reading more of the packet and eventually
  1336. ;          resetting the SCC for the next interrupt.
  1337. ;___________________________________________________________________________
  1338.  
  1339.             TST     D2                  ; Is there a protocol handler? (3.1F)
  1340.             BMI.S   @60                 ; Branch if not
  1341.             bsr     DoIUS               ; reset Highest IUS
  1342.             MOVEM.L A4/A5,SaveA45(A2)   ; Save A4 and A5 (may be free time now)
  1343.             move.l  LAPInBuf(a2),a4     ; point at the next char of the msg
  1344.             move.l  A4,LAPStash(a2)     ;    (we can snatch A4 for a few instrs)
  1345.             MOVE.L  Handlers(A2,D2),A5  ; A5 -> protocol handler
  1346.             LEA     ReadPacket,A4       ; A4 -> ReadPacket
  1347.             st      stillBusy(a2)       ; remember we're processing a frame
  1348.             move.w  VSCCEnable(A2),SR   ; re-enable so we can catch more chars (!)
  1349.  
  1350.             JSR     (A5)                ; Call the protocol handler
  1351.  
  1352.             move.l  MPPVars,A2          ; point at our variables
  1353.             cmpa.l  SaveA45(A2),A4      ; paranoia land -- make sure they've left
  1354.             bne.s   @45                 ;    things as they should be
  1355.             cmpa.l  (SaveA45+4)(A2),A5
  1356.             beq.s   @50
  1357. @45         pea     BadA4A5
  1358.             DC.W    $ABFF               ; print the text (in lieu of $A9FF)
  1359. @50         sf      stillBusy(A2)       ; and now we're not in a frame
  1360.             rts                         ; exit the interrupt handler
  1361. ;
  1362. ; No handler, just log the error
  1363. ;
  1364. @60         _StatCount NoHandCnt        ; Count packets without a handler
  1365.             bra     RIntRTS             ; and exit
  1366. BadA4A5     DC.B    17                  ; debugging only
  1367.             DC.B    'AALAP - Bad A4/A5'
  1368.             align 2
  1369.             EJECT
  1370. ;______________________________________________________________________
  1371. ;
  1372. ;   NextChar -- Handle the next char
  1373. ;
  1374. ;   This routine does two things:  If we're awaiting a full message, then
  1375. ;   it gets the next character.  That char may have arrived from the SCC,
  1376. ;   or it may be a char left in the BusyBuf. (Chars in the BusyBuf take
  1377. ;   precedence.)
  1378. ;
  1379. ;   If we're still processing the previous message (stillBusy set true),
  1380. ;   then all characters which arrive will be placed in BusyBuf, and the
  1381. ;   associated pointers updated.  (Note: myPollProc also inserts data
  1382. ;   into the BusyBuf, but it doesn't set stillBusy.)
  1383. ;
  1384. ;   Uses    A0,A1,D0
  1385. ;   Assumes A2 -> MPPVars
  1386. ;
  1387. ;   Returns Z if no character
  1388. ;           NZ if char present (char is in 8 lsbits of D0)
  1389. ;______________________________________________________________________
  1390.  
  1391. NextChar    _SUBR
  1392.             tst.b   stillBusy(A2)       ; are we still processing the prev.
  1393. frame?
  1394.             bne.s   @30                 ; go if we are
  1395.  
  1396.             bsr.s   GetBusyChar         ; else, look for a char from BusyBuf
  1397.             bne.s   @50                 ; quit if we got one
  1398.             bsr.s   GetSCCchar          ; else check the SCC
  1399.             bra.s   @50                 ; and quit
  1400.  
  1401. @30         bsr.s   StashSCCch          ; stash a char from SCC into BusyBuf
  1402.             bne.s   @30                 ; go back and look for more
  1403.  
  1404. @50         _SUBEND 'NEXTCHAR'
  1405.             _assumeEq BusyStash,BusyBuf+16 ; otherwise cmpa.l A0,A1 (above)
  1406. fails
  1407.  
  1408. GetBusyChar _SUBR                       ; get a char from the BusyBuf
  1409.             move.l  BusyFetch(A2),D0    ; get the fetch pointer
  1410.             cmp.l   BusyStash(A2),D0    ; is it the same as the stash pointer
  1411.             bne.s   @10                 ; go if not (more chars to do)
  1412.             lea     BusyBuf(a2),a0      ; point at the busy buffer
  1413.             move.l  a0,BusyStash(A2)    ; and save it in the BusyStash
  1414.             move.l  a0,BusyFetch(A2)    ; and BusyFetch
  1415.             moveq   #0,D0               ; clear the CC
  1416.             bra.s   @20
  1417. @10         move.l  D0,A0               ; there's still more to take
  1418.             move.b  (A0)+,D0            ; get the byte
  1419.             move.l  A0,BusyFetch(A2)    ; update the pointer
  1420.             or.w    #$100,D0            ; make CC <> Z (must preserve 8
  1421. lsbits)
  1422. @20         _SUBEND  'GETBUSYC'
  1423.             EJECT
  1424. ;______________________________________________________________________
  1425. ;
  1426. ; GetSCCchar and StashSCCch both are called by RintHnd and myPollProc
  1427. ; BOTH ROUTINES MAY ONLY USE A0, A1, AND D0!!!!!  (A2 will -> MPPVars)
  1428. ;
  1429. ;   GetSCCchar looks at RCA on the proper channel, and returns the char
  1430. ;   in D0 if there was one (with CC set <> Z); else it returns CC = Z.
  1431. ;______________________________________________________________________
  1432. GetSCCchar  movem.l SCCRd,A0/A1         ; forces A0/A1 to point at SCC
  1433.             IF      PortA THEN
  1434.             addq.l  #Actl,A0
  1435.             addq.l  #Actl,A1
  1436.             ENDIF
  1437.             btst    #RCAbit,(A0)        ; is there a char?
  1438.             beq.s   @20                 ; go if not
  1439.             move.b  #1,(a1)             ; point at the error bits from RR1
  1440.             nop
  1441.             move.b  (a0),D0             ; get them (Overrun,Framing) in D0
  1442.             and     #$70,D0             ; any error bits?
  1443.             beq.s   @10                 ; go if not
  1444.             move.b  #ResetErr,(a1)      ; else send Error Reset to WR0
  1445.             nop
  1446.             move.b  #1,(a1)             ; point at WR1
  1447.             nop
  1448.             move.b  #$13,(a1)           ; and set up for int on all rx chars
  1449.             nop
  1450.             _statcount OVRcount         ; count 'em
  1451. @10         move.b  SCCData(a0),D0      ; and get the data (EVEN IF ERROR!)
  1452.             or.w    #$100,D0            ; set the SR (to NZ -- there's a char)
  1453. @20         rts
  1454. ;
  1455. ;  StashSCCch -- take a char from SCC, save in BusyBuf if there's space
  1456. ;   Return Z if no char or no space; NZ otherwise
  1457. ;
  1458. StashSCCch  bsr.s   GetSCCchar          ; look for a char in the SCC
  1459.             beq.s   @50                 ; go if none
  1460.             lea     BusyStash(a2),A1    ; point at the BusyStash pointer
  1461.             move.l  (a1),A0             ; and get it
  1462.             cmpa.l  A0,A1               ; will this be too many chars?
  1463.             beq.s   @50                 ; yes, simply exit (and ignore the char)
  1464.             move.b  D0,(a0)+            ; save the char, and bump the pointer
  1465.             move.l  A0,BusyStash(A2)    ; and update the pointer
  1466.             or.w    #$100,D0            ; set the CC <> Z ('cause we took one )
  1467. @50         rts                         ; and return
  1468.             EJECT
  1469. ;______________________________________________________________________
  1470. ;
  1471. ; DoIUS  -- reset Highest IUS
  1472. ;______________________________________________________________________
  1473.  
  1474. DoIUS       _SUBR
  1475.             move.l  SCCWr,A1            ; point at the SCC write regs
  1476.             IF      PortA THEN
  1477.             addq.l  #Actl,A1
  1478.             ENDIF
  1479.             move.b  #ResetIUS,(a1)      ; Reset Highest IUS in SCC (to WR0)
  1480.             _SUBEND 'DOIUS   '
  1481.             EJECT
  1482. ;______________________________________________________________________
  1483. ;
  1484. ; LAPIn - it's a LAP control packet.
  1485. ;
  1486. ;   D0 = LAP type
  1487. ;   A3 -> remainder of the frame
  1488. ;   Note:  for IM/UR frames, the net number (2 bytes) is at (a3),
  1489. ;           but the node number (1 byte) is the first byte in LAPInBuf
  1490. ;______________________________________________________________________
  1491. ;
  1492. ; Check for IM
  1493. ;
  1494. LAPIn       move    (a3),D1             ; D1 = Net number (a3 sb even)
  1495.             move.l  LAPInBuf(a2),A0     ; point at first char in input buf
  1496.             move.b  (a0),D2             ; D2 = node number
  1497.             cmp.b   #lapIM,D0           ; is it an IM?
  1498.             bne.s   @60                 ; go if not
  1499.             move    D2,D0               ; D0 = node number
  1500.             sf      RcvdXoff(A2)        ; so we can start sending
  1501.             bsr.s   CheckIM             ; figure out the net and node to send
  1502.             bsr.s   SendIMUR            ; send 'em
  1503.             bra.s   @80
  1504. ;
  1505. ; Check for UR
  1506. ;
  1507. @60         cmp.b   #lapUR,D0           ; is it a UR?
  1508.             bne.s   @80                 ; go if not
  1509.             move    D2,D0               ; D0 = Node number (D1 = Net number)
  1510.             bsr.s   CheckUR             ; check these values, return <> 0 if OK
  1511.             sne     AALAPup(a2)         ; if non-zero, then we're up
  1512. @80         rts                         ; and return
  1513.  
  1514.             _AssumeEq   lapENQ,$81      ; (1)
  1515.             _AssumeEq   lapRTS,lapENQ+3 ; (2)
  1516.             _AssumeEq   lapCTS,lapRTS+1 ; (3)
  1517.             EJECT
  1518. ;__________________________________________________________________________
  1519. ;
  1520. ; CheckIM -- check the received IM frame, compute UR response
  1521. ;
  1522. ; Entry:  D0 = their node number
  1523. ;         D1 = their network number
  1524. ; Exit:   D0,D1 = node, net number for the UR
  1525. ;         D2 = qlapUR
  1526. ;         Changes A0,A1,A3, D0-D3
  1527. ;__________________________________________________________________________
  1528.  
  1529. CheckIM     move.l  #0,A0               ; return nil sometimes
  1530.             move.w  SysNetNum(a2),D2    ; D2 = our Net number
  1531.             beq.s   @10                 ; go if so -- check the node numbers
  1532.             move    D2,D1               ; else, use our net number
  1533. @10         move.b  SysLAPAddr(a2),D3   ; D3 = our node number
  1534. @15         tst.b   D0                  ; while (theirnode <> 0)
  1535.             beq.s   @18                 ; &     (theirnode <> mynode)
  1536.             cmp.b   D3,D0               ; have we both chosen the same value?
  1537.             bne.s   @20                 ; go if not -- return their value
  1538. @18         bsr     RandomWord          ; choose a random value
  1539.             and     #$7F,D0             ; mask to 7 bits
  1540.             bra.s   @15                 ; loop to insure they're different
  1541. @20         move.b  D0,sysABridge(a2)   ; remember their node number
  1542.             moveq   #qlapUR,D2          ; D2 = LAP type
  1543.             rts
  1544.  
  1545.             EJECT
  1546. ;__________________________________________________________________________
  1547. ;
  1548. ; CheckUR -- check the received UR frame
  1549. ;
  1550. ; Entry:  D0 = node number
  1551. ;         D1 = network number
  1552. ; Exit:   D0 =  0 if net/node didn't match
  1553. ;            <> 0 if they matched right off
  1554. ;
  1555. ;__________________________________________________________________________
  1556.  
  1557. CheckUR     SUBR
  1558.             cmp     SysNetNum(a2),D1    ; Network numbers match?
  1559.             bne.s   @10                 ; go if not
  1560.             cmp.b   SysLAPAddr(a2),D0   ; Node number match?
  1561.             bne.s   @10                 ; go if not
  1562.             moveq   #-1,D0              ; make D0 non-zero (it's OK)
  1563.             bra.s   CkURRTS             ; and exit
  1564. @10         tst     SysNetNum(a2)       ; is our network number 0000?
  1565.             bne.s   @50                 ; go if not (we cannot resolve this)
  1566.             move    D1,SysNetNum(a2)    ; save their Net/Node suggestions
  1567.             move.b  D0,SysLAPAddr(a2)
  1568.             bra.s   @60
  1569.  
  1570. @50         st      AALAPstuck(a2)      ; we're really bad off -- NNNN conflict
  1571. @60         clr     D0                  ; we didn't match
  1572.  
  1573. CkURRTS     _SUBEND 'CHECKUR '
  1574.             EJECT
  1575. ;_____________________________________________________________________
  1576. ;
  1577. ; SendIMUR - This routine fills and sends an IM or UR frame.  This is
  1578. ;   a bit dicey, since a UR may be required as a result of receiving
  1579. ;   an IM.  Since it's difficult to abort a frame already in progress,
  1580. ;   we finesse the problem by not sending the IM/UR frame.  Here's why
  1581. ;   it works:  
  1582. ;
  1583. ;   A UR response is only necessary in two cases:  
  1584. ;     a) we're trying to bring the link up, and the other guy said "IM";
  1585. ;     b) he hasn't heard from us, and he wants to make sure we're here.
  1586. ;
  1587. ;   For a), we shouldn't be talking, but he'll ask again anyway;
  1588. ;   for b), the IM is trying to force us to send a good frame.
  1589. ;           If the frame in transit makes it, OK.  If not, he'll
  1590. ;           still ask again.
  1591. ;
  1592. ; Entry:    A0 -> master pointer of this hdlblk
  1593. ;           A2 -> MPPVars
  1594. ;           D0 = node number
  1595. ;           D1 = Net number
  1596. ;           D2 = LAP type
  1597. ; Exit:     A0,A1,A3,D0-D3 changed
  1598. ;_____________________________________________________________________
  1599.  
  1600. SendIMUR    _SUBR
  1601.             tst.l   tWDSptr(A2)         ; are we sending?
  1602.             bne.s   SndIMUR1            ; yes, just return
  1603.             lea     IMURbuf+1(A2),A1    ; A1 points at IMURbuf (odd adrs)
  1604.             move.b  D2,2(a1)            ; save the LAPtype (IM or UR)
  1605.             move.w  D1,3(a1)            ; and the Net number
  1606.             move.b  D0,5(a1)            ; and the Node number
  1607.  
  1608.             lea     IMURwds(A2),A0      ; A0 points at the WDS
  1609.             move.w  #6,(A0)             ; save the length
  1610.             move.l  A1,2(A0)            ; and the pointer to the data
  1611.             clr.w   6(A0)               ; 
  1612.  
  1613.             st      SendingIMUR(A2)     ; remember this!
  1614.             bsr     SendFrame           ; and send it
  1615. SndIMUR1    _SUBEND 'SENDIMUR'
  1616.             EJECT
  1617. ;___________________________________________________________________________
  1618. ;
  1619. ;   ReadPacket - read in the specified number of bytes into the specified
  1620. ;       buffer. It is an error to request more bytes than have been received.
  1621. ;
  1622. ;   ReadRest - read in the rest of the packet, putting the specified number
  1623. ;       of bytes into the specified buffer.  Error if packet longer than buffer.
  1624. ;
  1625. ;   Call:
  1626. ;       A0,A1,A2 = SCC read and write addresses and local variables
  1627. ;       A3 -> buffer to read into
  1628. ;       A4 -> start of ReadPacket
  1629. ;       D3 =  byte count to read (word)
  1630. ;
  1631. ;   Return:
  1632. ;       D0 changed
  1633. ;       D1 number of chars still unread (ReadPacket); modified (ReadRest)
  1634. ;       D2 saved
  1635. ;       D3  = 0 if exact number of bytes requested were read
  1636. ;           > 0 indicates number of bytes requested but not read
  1637. ;               (packet smaller than requested maximum)
  1638. ;           < 0 indicates number of extra bytes read but not returned
  1639. ;               (packet larger than requested maximum)
  1640. ;       A0,A1 preserved by ReadPacket, modified by ReadRest
  1641. ;       A3 -> one past where last character went
  1642. ;       A4,A5 saved (until packet's all in or error)
  1643. ;
  1644. ; NOTE: CRC bytes not included in counts
  1645. ;___________________________________________________________________________
  1646.  
  1647. ReadPacket  BRA.S   DoRP                ; Need this for two entry points
  1648.  
  1649. ReadRest    movem.l a0/a1/D2,-(sp)      ; save some regs
  1650.             move    RcvdLen(a2),D1      ; get the number of remaining chars in D1
  1651.             move    D1,D0               ; we expect to copy D1 bytes
  1652.             move    #0,-(sp)            ; and expect good return status
  1653.             sub     D1,D3               ; compute (D3 - D1)
  1654.             bpl.s   @1                  ; go if we should copy D1 bytes (it fits)
  1655.             add     D3,D0               ; otherwise, copy D3 bytes (d1 + (d3-d1))
  1656.             move    #-1,(sp)            ; and set error return status
  1657. @1          movem.l SaveA45(a2),a4/a5   ; restore A4 and A5
  1658.             bra.s   DoCopy              ; and go to the common code
  1659.  
  1660. DoRP        movem.l a0/a1/D2,-(sp)      ; push some regs
  1661.             move    RcvdLen(a2),D1      ; get the number of remaining chars in D1
  1662.             move    D1,D0               ; assume we'll copy them all
  1663.             move    #-1,-(sp)           ; and that there's an error
  1664.             sub     D3,D1               ; update D1 (remaining bytes in buf)
  1665.             bmi.s   DoCopy              ; go if it's negative (error)
  1666.             move    D3,D0               ; we'll read what they asked for (D3)
  1667.             clr     (sp)                ;  and remember that it's exactly right
  1668.             clr     D3                  ;
  1669.  
  1670. DoCopy      move.l  LAPStash(A2),a0     ; point at the source data
  1671.             ext.l   D0                  ; belt and suspenders (D0 = actual length)
  1672.             add.l   D0,LAPStash(A2)     ;    and update the LAPStash value
  1673.             sub     D0,RcvdLen(a2)      ;    and the num chars remaining
  1674.             move.l  A3,A1               ; point at the dest buffer
  1675.             lea     0(A3,D0),A3         ; update the return pointer
  1676.             _BlockMove                  ; Do It
  1677.             move    RcvdLen(a2),D1      ; return number of unread chars
  1678.             move    (sp)+,d0            ; get the return status back
  1679.             movem.l (sp)+,a0/a1/D2      ; get the other registers
  1680.             tst      D0                 ; set the CCR
  1681.             rts
  1682.             EJECT
  1683. ;___________________________________________________________________________
  1684. ;
  1685. ; NextCRC -- compute a CRC on the word pointed at by A3 and the char in D0
  1686. ;
  1687. ;      This routine computes a CRC-16 on a stream of bytes.  It uses a
  1688. ;      table lookup scheme to implement a x^16 + x^15 + x^2 + 1 polynomial.
  1689. ;      The interested reader is referred to McNamara's Technical Aspects
  1690. ;      of Data Communications, second edition, pps 110-122 for an obliquely
  1691. ;      related discussion.
  1692. ;
  1693. ;      This routine takes the storage short cut of looking up two four-bit
  1694. ;      values in a 16-entry table instead of one eight-bit value in a 256
  1695. ;      word table.  This saves a considerable amount of space (32 bytes vs.
  1696. ;      512 bytes for the table).
  1697. ;
  1698. ;      One pass thru this routine (one character) is about 262 cycles, or
  1699. ;      33.45 usec on a Mac.  This is a data rate of ~29,900 char/sec,
  1700. ;      or plenty fast to keep up with a 9600 baud link.
  1701. ;
  1702. ; Entry:  A3 -> CRC accumulator
  1703. ;         D0    LSbyte is the data char (already masked to 8 bits)
  1704. ;
  1705. ; Exit:   D1,D2 changed
  1706. ;         Other regs unchanged
  1707. ;____________________________________________________________________________
  1708.  
  1709. NextCRC _SUBR      0               ; for macsbug
  1710.        move        (a3),D2         ; D2 is the temp accumulator
  1711.        move        D0,D1           ; make a copy of the input character
  1712. ; first work on the least significant nibble
  1713.        eor         D2,D1           ; xor the accumulator with the data char
  1714.        and         #$0F,D1         ;    to get an index into the CRCTable
  1715.        add         D1,D1           ; to make a word index
  1716.        lsr         #4,D2           ; shift the CRC right four bits
  1717.        move        CRCTable(D1),D1
  1718.        eor         D1,D2           ; and mask it with the approp. table entry
  1719.        move        D0,D1
  1720.        lsr         #4,D1           ; shift the data char right four bits
  1721. ;  and do it again for the high nibble
  1722.        eor         D2,D1           ; xor the accumulator with the data char
  1723.        and         #$0F,D1         ;    to get an index into the CRCTable
  1724.        add         D1,D1           ; to make a word index
  1725.        lsr         #4,D2           ; shift the CRC right four bits
  1726.        move        CRCTable(D1),D1 ; and mask it with the approp. table entry
  1727.        eor         D1,D2
  1728.        move        D2,(a3)         ; remember this CRC for next time
  1729.        _SUBEND     'NEXTCRC '
  1730.  
  1731. CRCTable DC.W      $0000,$CC01,$D801,$1400
  1732.        DC.W        $F001,$3C00,$2800,$E401
  1733.        DC.W        $A001,$6C00,$7800,$B401
  1734.        DC.W        $5000,$9C01,$8801,$4400
  1735.             EJECT
  1736. ;
  1737. *  * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *
  1738. * * * * * * * ****
  1739. ;___________________________________________________________________________
  1740. ;
  1741. ; MDoWarn -- Control call to put up a warning
  1742. ;
  1743. ; Entry:    A0 -> IOQelement
  1744. ;___________________________________________________________________________
  1745.  
  1746. MDoWarn     move    CSParam(a0),D0      ; get the error code into D0
  1747.             bsr.s   DoWarn              ; warn 'em and return status in D0
  1748.             bra     AbusExit            ; and exit
  1749.  
  1750. ; Put up alerts
  1751. ;____________________________________________________________________
  1752. ;
  1753. ;   DoWarn -- Warn the user...  Give a beep, and display a dialog;
  1754. ;             wait for their choice, then try the NNNN one more time.
  1755. ;             If they choose "Use new address" from Mismatch dialog,
  1756. ;             set SysLAPaddr and SysNetNum to zero before exiting.
  1757. ;
  1758. ;   Entry:   D0 = PortNotCf
  1759. ;                 noAnswer
  1760. ;   Exit:    D0 = -4001 (user clicked OK/Try again)
  1761. ;   -4002  (user clicked Use New)
  1762. ;  -193  (ResFNotFound)
  1763. ;____________________________________________________________________
  1764.  
  1765. resfile     EQU     -2                  ; res file number
  1766. dlgwindow   EQU     -6                  ; dialog window handle
  1767. warning     EQU     -8                  ; error number/return status
  1768. MyCurMap    EQU     -10                 ; save the current res file
  1769.  
  1770. DoWarn      _SUBR   10                  ; Warn the user about troubles
  1771.  
  1772.             move.w  D0,warning(A6)      ; remember the warning
  1773.             move.w  CurMap,MyCurMap(A6) ; and the current res file
  1774.             InitCursor                  ; make it an arrow again
  1775.  
  1776. ; Open our resource file.
  1777.  
  1778.             subq.l  #2,sp               ; make space for result
  1779.             pea     fileName            ; point to file name
  1780.             OpenResFile
  1781.             move.w  (SP)+,resfile(A6)   ; save the resfile number
  1782.             cmp.w   #-1,resfile(a6)     ; check for failure
  1783.             bne.s   @3                  ; branch if ok
  1784.             move.w  #60,-(A7)           ; else beep (long)
  1785.             SysBeep
  1786.             move.w  #ResFNotFound,D0    ; return bad status
  1787.             bra.s   @20                 ; and quit
  1788.  
  1789. ; beep at 'em
  1790. @3
  1791.             move.w  #6,-(A7)            ; 1/10 second beep
  1792.             _SysBeep
  1793.  
  1794. ; choose a dialog to display
  1795.             move.w  #PortNCalrt,D0
  1796.             cmp.w   #PortNotCf,warning(a6) ; which warning?
  1797.             beq.s   @5
  1798.             move.w  #Noansalrt,D0       ; noAnswer dialog
  1799.  
  1800. ; now display the dialog
  1801. @5
  1802.             subq.l  #4,sp               ; space for result of _GetNewDialog
  1803.             move.w  D0,-(sp)            ;    dialog resource ID
  1804.             clr.l   -(sp)               ;    dialog record in heap
  1805.             move.l  #-1,-(sp)           ;    in front of other windows
  1806.             _GetNewDialog
  1807.             move.l  (SP)+,dlgwindow(A6) ; save the dialog's handle
  1808.  
  1809. ;  Now do the dialog stuff
  1810.  
  1811.             subq.l  #2,sp               ; result on stack
  1812.             clr.l   -(sp)               ; normal filterproc
  1813.             pea     4(sp)               ; point to result space
  1814.             _ModalDialog                ;    Do it
  1815.  
  1816. ; discard dialog
  1817.  
  1818.             move.l  dlgWindow(a6),-(sp) ; point to dialog
  1819.             _DisposDialog
  1820.  
  1821. ; What did they hit?
  1822.  
  1823.             move.w  (sp)+,d0            ; get the button's item #
  1824.             cmp.w   #1,D0               ; (Try Again or OK (=1)) or Use New?
  1825.             beq.s   @10                 ; go if not "Use New"
  1826.             clr.b   SysLAPAddr(a2)      ; otherwise, Use New
  1827.             clr.w   SysNetNum(a2)       ;   and reset net and node adrs
  1828.  
  1829. @10         neg.l   D0                  ; item will be 1 or 2; return -4001
  1830.             sub.l   #4000,D0            ;     or -4002 as the status
  1831.             move.w  D0,warning(A6)      ; save it 
  1832.  
  1833. ; discard resource file
  1834.  
  1835.             move.w  resfile(A6),D0      ; get the refnum
  1836.             cmp.w   MyCurMap(A6),D0     ; was it the current resource file
  1837.             beq.s   @15                 ; go if so (someone else opened it)
  1838.             move.w  D0,-(sp)            ; else, push it
  1839.             CloseResFile                ; and close it
  1840. @15         move.w  warning(A6),D0      ; get the status from the NNNN
  1841.  
  1842. @20  ; D0 is result code for this routine
  1843.            _SUBEND 'DOWARN  '           ; and exit
  1844.  
  1845. FileName    DC.B    15
  1846.             DC.B    'Async AppleTalk'
  1847.             DC.B    'V1.2a6' 
  1848.             ALIGN   2
  1849.  
  1850. ; ****** end of lap.a
  1851.  
  1852.  
  1853.  
  1854.  
  1855.  
  1856.  
  1857.  
  1858.  
  1859.  
  1860.  
  1861. Listing 2
  1862.  
  1863. CRC Calculations
  1864.  
  1865.      This file contains a CRC calculation in Pascal.  It was used with
  1866.      preliminary versions of Async AppleTalk, and computes the same 
  1867.      function as the code in the M68000 listing.
  1868.  
  1869.      The NextCRC algorithm simulates the feedback shift register which
  1870.      normally implements a CRC calculation.  NextCRC takes each four-
  1871.      bit nibble of the input char and uses a table (crctbl) to select
  1872.      a mask which is exclusive-or'd with the current CRC accumulator.
  1873. }
  1874.  
  1875. { pseudo-CONST -- put this in the initialization code of your program
  1876.  
  1877. crctbl[00] := $0000; crctbl[01] := $CC01;
  1878. crctbl[02] := $D801; crctbl[03] := $1400;
  1879. crctbl[04] := $F001; crctbl[05] := $3C00;
  1880. crctbl[06] := $2800; crctbl[07] := $E401;
  1881. crctbl[08] := $A001; crctbl[09] := $6C00;
  1882. crctbl[10] := $7800; crctbl[11] := $B401;
  1883. crctbl[12] := $5000; crctbl[13] := $9C01;
  1884. crctbl[14] := $8801; crctbl[15] := $4400;
  1885. }
  1886.  
  1887. VAR crctbl : array [0..15] of integer;
  1888.  
  1889. function NextCRC (crc : integer; c : QDbyte) : integer;
  1890.  
  1891. VAR
  1892.      j : integer;
  1893.  
  1894. BEGIN
  1895.      j := crctbl[ band(bxor(crc,c),$000F) ];
  1896.      crc := bxor(bsr(crc,4),j);
  1897.      c := bsr(c,4);
  1898.      j := crctbl[ band(bxor(crc,c),$000F) ];
  1899.      crc := bxor(bsr(crc,4),j);
  1900.      nextcrc := crc;
  1901. END; { NextCRC }
  1902.  
  1903. function crc16 (p : qdptr; len : integer) : integer;
  1904. VAR
  1905.    i,j : integer;     { sixteen bits wide }
  1906.    c   : qdbyte;      { an eight bit value }
  1907.    crc : integer;     { the CRC accumulator }
  1908.  
  1909. BEGIN
  1910.    crc := 0;
  1911.    for i := 1 to len do begin
  1912.        c := p^;
  1913.        p := pointer(ord(p) + 1);
  1914.        crc := NextCRC(crc,c);
  1915.    end;
  1916.    crc16 := crc;
  1917. END; { crc16 }
  1918.  
  1919.  
  1920.  
  1921.  
  1922.  
  1923. Listing 3
  1924.  
  1925. ;
  1926. ; _AssumeEq  Arg1, Arg2 -- macro to generate a compile-time error if two
  1927. ;                          arguments are unequal.
  1928. ;
  1929. ;         To optimize code size, we will be making various assumptions,
  1930. ;         mainly as to offset values. This macro is a way of formalizing
  1931. ;         those assumptions within the code.
  1932. ;
  1933.  
  1934.     BLANKS ON
  1935.     STRING ASIS
  1936.  
  1937.           MACRO              
  1938.           _AssumeEq
  1939.                IF  &Eval(&Syslst[1]) <> &Eval(&Syslst[2]) THEN
  1940.                     _ERR           ; Invalid statement - will cause error
  1941.                ENDIF
  1942.           ENDM 
  1943. ;
  1944. ; _StatCount Arg1 -- increment a statistics count if stat keeping is enabled
  1945. ;
  1946. ;         Assumes A2 points to the driver variables
  1947. ;
  1948.  
  1949.           MACRO               
  1950.           _StatCount
  1951.                IF  debug THEN
  1952.                     ADDQ.L  #1,&Syslst[1](A2); Update the count
  1953.                ELSE 
  1954. .*                   nop   ; commented out
  1955.                ENDIF
  1956.           ENDM 
  1957.  
  1958. ;
  1959. ; _Subr        -- assembles a "Link A6,#???"
  1960. ;                 works for _SUBR <no param>   and  _SUBR ###
  1961. ;
  1962.           MACRO          
  1963.           _Subr     &size
  1964.           IF        &size = '' THEN
  1965.           Link      A6,#0
  1966.           ELSE 
  1967.           Link      A6,#(-&size)
  1968.           ENDIF
  1969.           ENDM 
  1970.  
  1971. ;
  1972. ; _Subend  NAME,$xx  -- Subroutine epilog
  1973. ;                         If debugging, put in Unlk and the name
  1974. ;
  1975.           MACRO            
  1976.           _Subend    &name
  1977.           Unlk      A6        ; unlink the stack frame
  1978.           rts                 ; and return
  1979.           DC.B      &name     ; the name
  1980.           ALIGN     2
  1981.           ENDM
  1982.  
  1983.